# シク式ローカル出撃選択インクル
# 最終更新日22/04/18

# ・名称、レベルソートの時、量産機などの同名ユニットに乗っているとリストに表示されない不具合を修正。

# ・ソートボタンに「加入順」を追加。デフォルト設定ではこれになる。
# ・リストの昇順、降順を設定できるようにした。デフォルトは昇順。
# ・設定保存ボタンを追加。チェックを入れると次回選択画面で同じ設定が適用されるようになった。
# ・出撃可能数＞出撃可能な味方の時、すべて選択したら確認画面へ移行するようにした。
# ・新たなオプションに「スキップ」を追加。選択ユニットをリストを残し、配置を行わずに終了する。

# Call 出撃選択開始 出撃人数(最大20) X座標 Y座標 オプション

# オプションには「非同期」「アニメ非表示」「スキップ」を設定可能。
# 「スキップ」を設定した場合、出撃リストだけ残しユニット配置は行わない。
# リストを参照しつつ、シナリオに合わせて手動でユニットを配置させたい場合に使ってください。


出撃選択開始:
# ■インクル開始、ローカル変数の設定と出撃可能なメンバーの読み込み
Local i j k CELE_U_BMP CELE_U_N CELE_TXT PageNum
Local BACKIMAGE = Anime\CU_Back\EFFECT_default(Ally)01.gif
　PageNum = 0
Set 味方リスト ""
Set 出撃リスト ""

# グローバルスイッチがオンになっていた場合、保存していた設定を反映してソート
If 出撃選択保存設定 = オン Then
　Set CELE_SORT LIndex(出撃選択保存設定[内容],1)
　Set CELE_UPDOWN  LIndex(出撃選択保存設定[内容],2)
Else
　Set CELE_SORT 加入
　Set CELE_UPDOWN 昇順
EndIf

Center Args(2) Args(3)
# なうろーでぃんぐ
Line 0 220 480 260 RGB(0, 0, 0) BF
Font 20pt ゴシック Bold RGB(255, 255, 255)
PaintString - - Now Loading…
Font 10pt ゴシック Regular
Refresh

Call 出撃メンバーリスト作成 CELE_SORT CELE_UPDOWN


出撃選択更新場面:
# ■リストを元に項目設定、再描画はここから
PaintPicture BACKIMAGE - -40 512 320 上下反転 明 白黒
PaintPicture BACKIMAGE - 200 512 320 明 白黒

CELE_TXT = ("出撃メンバー選択：残り" & Args(1) - LLength(出撃リスト) & "人")
Font 20pt Ｐ明朝 Bold Italic RGB(30, 30, 30)
　PaintString 82 5 CELE_TXT
　PaintString 81 4 CELE_TXT
　PaintString 81 2 CELE_TXT
　PaintString 79 2 CELE_TXT
　PaintString 80 2 CELE_TXT
　PaintString 80 4 CELE_TXT
Font RGB(200, 255, 230)
　PaintString 80 3 CELE_TXT

# ソートボタン配置
　j = 0
For i = 1 To 6
　Line (1 + j * 70) 35 (71 + j * 70) 61 RGB(0, 0, 0) BF
　Line (2 + j * 70) 36 (70 + j * 70) 60 RGB(255, 255, 255) BF
　Line (3 + j * 70) 37 (70 + j * 70) 60 RGB(150, 150, 150) BF
　Line (3 + j * 70) 37 (69 + j * 70) 59 RGB(50, 50, 50) BF
　Incr j
Next
Font 13pt Ｐゴシック Regular

If CELE_SORT = 名称 Then
　Font RGB(255, 0, 0)
Else
　Font RGB(255, 255, 255)
　HotPoint ソート名称 1 35 70 26 名称順に並べ替え
EndIf
PaintString 20 39 名称

If CELE_SORT = レベル Then
　Font RGB(255, 0, 0)
Else
　Font RGB(255, 255, 255)
　HotPoint ソートレベル 71 35 70 26 パイロットレベル順に並べ替え
EndIf
PaintString 85 39 レベル

If CELE_SORT = ランク Then
　Font RGB(255, 0, 0)
Else
　Font RGB(255, 255, 255)
　HotPoint ソートランク 141 35 70 26 ユニットランク順に並べ替え
EndIf
PaintString 157 39 ランク

If CELE_SORT = ＨＰ Then
　Font RGB(255, 0, 0)
Else
　Font RGB(255, 255, 255)
　HotPoint ソートＨＰ 211 35 70 26 ＨＰが高い順に並べ替え
EndIf
PaintString 236 39 ＨＰ

If CELE_SORT = 移動力 Then
　Font RGB(255, 0, 0)
Else
　Font RGB(255, 255, 255)
　HotPoint ソート移動力 281 35 70 26 移動力が高い順に並べ替え
EndIf
PaintString 292 39 移動力

If CELE_SORT = 加入 Then
　Font RGB(255, 0, 0)
Else
　Font RGB(255, 255, 255)
　HotPoint ソート加入順 351 35 70 26 加入した順番に並べ替え
EndIf
PaintString 372 39 加入


# 自動選択ボタン配置
　j = 0
For i = 1 To 2
　Line (1 + j * 119) 61 (120 + j * 119) 87 RGB(0, 0, 0) BF
　Line (2 + j * 119) 62 (119 + j * 119) 86 RGB(255, 255, 255) BF
　Line (3 + j * 119) 63 (119 + j * 119) 86 RGB(150, 150, 150) BF
　Line (3 + j * 119) 63 (118 + j * 119) 85 RGB(50, 50, 50) BF
　Incr j
Next
　Font RGB(255, 255, 255)
PaintString 10 65 先頭から選択
　HotPoint 自動選択１ 1 61 119 26 先頭から全て選択
PaintString 130 65 最後から選択
　HotPoint 自動選択２ 120 61 119 26 最後から全て選択


# 昇降切り替えボタン配置
　Line 250 61 305 87 RGB(0, 0, 0) BF
　Line 251 62 304 86 RGB(255, 255, 255) BF
　Line 252 63 304 86 RGB(150, 150, 150) BF
　Line 252 63 303 85 RGB(50, 50, 50) BF
　Font RGB(255, 255, 255)
If CELE_UPDOWN = 降順 Then
　PaintString 261 65 昇順
　　HotPoint 昇降切り替え 250 61 55 26 昇順に切り替える
Else
　PaintString 261 65 降順
　　HotPoint 昇降切り替え 250 61 55 26 降順に切り替える
EndIf


# 設定保存ボタン配置
 FillStyle 透明
 Line 316 63 400 85 RGB(0, 0, 0) BF
 Line 317 64 399 84 RGB(50, 50, 50) BF
 Line 319 66 334 82 RGB(255, 255, 255) BF
 Line 320 67 333 81 RGB(0, 0, 0) B
　Font 9pt Ｐゴシック Regular RGB(255, 255, 255)
　PaintString 339 68 設定を保存
　HotPoint 設定保存スイッチ 316 63 84 22 設定を保存する
　If 出撃選択保存設定 = オン Then
　　DrawWidth 2
　　Line 322 73 325 78 RGB(255, 0, 0)
　　Line 325 77 331 71 RGB(255, 0, 0)
　　DrawWidth 1
　EndIf



# ユニットリスト表示
　j = 0
　k = 0
For i = (PageNum * 18 + 1) To (PageNum * 18 + 18)
　If LIndex(味方リスト,i) = "" Then
　　Break
　EndIf
　CELE_U_N = LIndex(味方リスト,i)
　CELE_U_BMP = Info(ユニット, Unit(CELE_U_N), グラフィック)

# 枠組
　FillStyle 塗りつぶし
　Color RGB(255, 255, 255)
　FillColor RGB(255, 255, 255)
　　Polygon (0 + j * 159) (136 + k * 46)  (10 + j * 159) (98 + k * 46)  (160 + j * 159) (98 + k * 46)  (150 + j * 159) (136 + k * 46)
　Color RGB(0, 0, 0)
　FillStyle 塗りつぶし
　FillColor RGB(30, 30, 30)
　　Polygon (2 + j * 159) (136 + k * 46)  (12 + j * 159) (98 + k * 46)  (158 + j * 159) (98 + k * 46)  (148 + j * 159) (136 + k * 46)
　FillStyle 網かけ
　FillColor RGB(0, 0, 0)
　　Polygon (2 + j * 159) (136 + k * 46)  (12 + j * 159) (98 + k * 46)  (158 + j * 159) (98 + k * 46)  (148 + j * 159) (136 + k * 46)

# 画像、ホットポイント設置
　If LSearch(出撃リスト,CELE_U_N) > 0 Then
　　PaintPicture CELE_U_BMP (8 + j * 159) (102 + k * 46) シルエット 透過
　　PaintPicture CELE_U_BMP (5 + j * 159) (100 + k * 46) 透過 白黒 暗
　　HotPoint ("解除_" & CELE_U_N) (10 + j * 159) (98 + k * 46) 140 38 (Nickname(CELE_U_N) & "を選択から外す")
　Else
　　PaintPicture CELE_U_BMP (8 + j * 159) (102 + k * 46) シルエット 透過
　　PaintPicture CELE_U_BMP (5 + j * 159) (100 + k * 46) 透過
　　HotPoint CELE_U_N (10 + j * 159) (98 + k * 46) 140 38 Info(ユニット, Unit(CELE_U_N), 愛称)
　EndIf

# 名前とステータス表示
　Font 9pt Ｐゴシック Regular RGB(255, 255, 255)
　　PaintString (40 + j * 159) (100 + k * 46) Nickname(CELE_U_N)
　　Switch CELE_SORT
　　Case ランク
　　　PaintString (40 + j * 159) (112 + k * 46) ("Rk：" & Rank(CELE_U_N))
　　　PaintString (40 + j * 159) (124 + k * 46) ("Lv：" & Level(CELE_U_N))
　　　PaintString (90 + j * 159) (112 + k * 46) ("HP：" & HP(CELE_U_N))
　　　PaintString (90 + j * 159) (124 + k * 46) ("EN：" & EN(CELE_U_N))
　　Case ＨＰ
　　　PaintString (40 + j * 159) (112 + k * 46) ("HP：" & HP(CELE_U_N))
　　　PaintString (40 + j * 159) (124 + k * 46) ("Lv：" & Level(CELE_U_N))
　　　PaintString (90 + j * 159) (124 + k * 46) ("EN：" & EN(CELE_U_N))
　　Case 移動力
　　　PaintString (40 + j * 159) (112 + k * 46) ("移動：" & Info(ユニット, Unit(CELE_U_N), 移動力))
　　　PaintString (40 + j * 159) (124 + k * 46) ("Lv：" & Level(CELE_U_N))
　　　PaintString (90 + j * 159) (112 + k * 46) ("HP：" & HP(CELE_U_N))
　　　PaintString (90 + j * 159) (124 + k * 46) ("EN：" & EN(CELE_U_N))
　　Case Else
　　　PaintString (40 + j * 159) (112 + k * 46) ("Lv：" & Level(CELE_U_N))
　　　PaintString (90 + j * 159) (112 + k * 46) ("HP：" & HP(CELE_U_N))
　　　PaintString (90 + j * 159) (124 + k * 46) ("EN：" & EN(CELE_U_N))
　　EndSw
　Incr j
　If j = 3 Then
　　j = 0
　　Incr k
　EndIf
Next


　j = 0
　k = 0
# 選択済みユニット表示
For i = 1 To 20
　Font 9pt Ｐゴシック Bold RGB(255, 0, 0)
　If Args(1) < i Then
　　PaintPicture Anime\Common\EFFECT_Tile(Ally).bmp (44 + j * 40) (376 + k * 40) 暗 暗
　Else
　　PaintPicture Anime\Common\EFFECT_Tile(Ally).bmp (44 + j * 40) (376 + k * 40)
　　PaintString (74 - TextWidth(i) + j * 40) (396 + k * 40) i
　　If LIndex(出撃リスト,i) != "" Then
　　　CELE_U_N = LIndex(出撃リスト,i)
　　　CELE_U_BMP = Info(ユニット, Unit(CELE_U_N), グラフィック)
　　　PaintPicture CELE_U_BMP (44 + j * 40) (376 + k * 40) 透過
　　　HotPoint ("解除_" & CELE_U_N) (44 + j * 40) (376 + k * 40) 32 32 (Nickname(CELE_U_N) & "を選択から外す")
　　EndIf
　EndIf
　Incr j
　If j = 10 Then
　　j = 0
　　Incr k
　EndIf
Next


# ページ移動と終了ボタン
Color RGB(0,0,0)
FillStyle 塗りつぶし
FillColor RGB(255, 255, 255)
Polygon 172 453  68 453  56 465  68 477  172 477
Polygon 308 453  412 453  424 465  412 477  308 477
Line 178 453 302 477 RGB(0, 0, 0) B

FillColor RGB(50, 50, 50)
Polygon 170 455  70 455  60 465  70 475  170 475
Polygon 310 455  410 455  420 465  410 475  310 475
Line 180 455 300 475 RGB(0, 0, 0) B

If LLength(味方リスト) > (18 + PageNum * 18) Then
　Font 13pt Ｐゴシック Regular RGB(255, 255, 255)
　HotPoint NextListPage 308 453 116 24 次のページへ移動する
Else
　Font 13pt Ｐゴシック Regular RGB(80, 80, 80)
EndIf
PaintString 335 455  Next→

If PageNum > 0 Then
　Font 13pt Ｐゴシック Regular RGB(255, 255, 255)
　HotPoint BackListPage 56 453 116 24 前のページへ移動する
Else
　Font 13pt Ｐゴシック Regular RGB(80, 80, 80)
EndIf
PaintString 95 455  ←Back

If LLength(出撃リスト) > 0 Then
　Font 11pt Ｐゴシック Regular RGB(255, 255, 255)
　HotPoint 終了 180 455 120 20 出撃選択を終了する
Else
　Font 11pt Ｐゴシック Regular RGB(80, 80, 80)
EndIf
PaintString - 457 選択を終了する

#PaintString 1 1 LLength(味方リスト)


# ■項目配置ここまで、描画して選択待ち
# ユニット選択数が出撃枠の上限になった、あるいは枠が残っていても味方をすべて選択していたら進行
Refresh
Do
If LLength(出撃リスト) < Args(1) And (LLength(出撃リスト) < LLength(味方リスト)) Then
　Wait Click
EndIf
Loop While (選択 = "" or (LLength(出撃リスト) > Args(1)))
ClearObj

# 最大人数まで選んだら出撃するかを確認
If (LLength(出撃リスト) = Args(1)) or (LLength(出撃リスト) = LLength(味方リスト)) Then
　Confirm この編成で出撃を終了しますか？
　If 選択 = 1 Then
　　Goto 出撃選択完了
　Else
# いいえの場合は最後の１人をキャンセルする
　　Set 新出撃リスト ""
　　For i = 1 To (LLength(出撃リスト) - 1)
　　　If LLength(新出撃リスト) = 0 Then
　　　　新出撃リスト = LIndex(出撃リスト,i)
　　　Else
　　　　新出撃リスト = (新出撃リスト & " " & LIndex(出撃リスト,i))
　　　EndIf
　　Next
　　出撃リスト = 新出撃リスト
　　UnSet 新出撃リスト
　　Goto 出撃選択更新場面
　EndIf
EndIf


# 選択ごとの処理
Switch 選択
Case NextListPage
　Playsound Page.wav
　Incr PageNum

Case BackListPage
　Playsound Page.wav
　Incr PageNum -1

Case 自動選択１
　Playsound Sword.wav
　Set 新出撃リスト ""
　For i = 1 To Args(1)
　　If LLength(新出撃リスト) = 0 Then
　　　新出撃リスト = LIndex(味方リスト,i)
　　Else
　　　新出撃リスト = (新出撃リスト & " " & LIndex(味方リスト,i))
　　EndIf
　Next
　出撃リスト = 新出撃リスト
　UnSet 新出撃リスト

Case 自動選択２
　Playsound Sword.wav
　Set 新出撃リスト ""
　For i = 1 To Args(1)
　　If LLength(新出撃リスト) = 0 Then
　　　新出撃リスト = LIndex(味方リスト,LLength(味方リスト) - i + 1)
　　Else
　　　新出撃リスト = (新出撃リスト & " " & LIndex(味方リスト,LLength(味方リスト) - i + 1))
　　EndIf
　Next
　出撃リスト = 新出撃リスト
　UnSet 新出撃リスト

Case 昇降切り替え
　Playsound Swing.wav
　PageNum = 0
　If CELE_UPDOWN = 降順 Then
　　CELE_UPDOWN = 昇順
　Else
　　CELE_UPDOWN = 降順
　EndIf
　Line 0 220 480 260 RGB(0, 0, 0) BF
　Font 20pt ゴシック Bold RGB(255, 255, 255)
　PaintString - - Now Loading…
　Font 10pt ゴシック Regular
　Refresh
　Call 出撃メンバーリスト作成 CELE_SORT CELE_UPDOWN

Case 設定保存スイッチ
　If 出撃選択保存設定 = オン Then
　　Playsound UnitOn.wav
　　UnSet 出撃選択保存設定
　Else
　　Playsound System.wav
　　Global 出撃選択保存設定
　　Set 出撃選択保存設定 オン
　EndIf

Case ソート名称
　Playsound Page.wav
　PageNum = 0
　CELE_SORT = 名称
　Line 0 220 480 260 RGB(0, 0, 0) BF
　Font 20pt ゴシック Bold RGB(255, 255, 255)
　PaintString - - Now Loading…
　Font 10pt ゴシック Regular
　Refresh
　Call 出撃メンバーリスト作成 CELE_SORT CELE_UPDOWN


Case ソートレベル
　Playsound Page.wav
　PageNum = 0
　CELE_SORT = レベル
　Line 0 220 480 260 RGB(0, 0, 0) BF
　Font 20pt ゴシック Bold RGB(255, 255, 255)
　PaintString - - Now Loading…
　Font 10pt ゴシック Regular
　Refresh
　Call 出撃メンバーリスト作成 CELE_SORT CELE_UPDOWN

Case ソートランク
　Playsound Page.wav
　PageNum = 0
　CELE_SORT = ランク
　Line 0 220 480 260 RGB(0, 0, 0) BF
　Font 20pt ゴシック Bold RGB(255, 255, 255)
　PaintString - - Now Loading…
　Font 10pt ゴシック Regular
　Refresh
　Call 出撃メンバーリスト作成 CELE_SORT CELE_UPDOWN


Case ソートＨＰ
　Playsound Page.wav
　PageNum = 0
　CELE_SORT = ＨＰ
　Line 0 220 480 260 RGB(0, 0, 0) BF
　Font 20pt ゴシック Bold RGB(255, 255, 255)
　PaintString - - Now Loading…
　Font 10pt ゴシック Regular
　Refresh
　Call 出撃メンバーリスト作成 CELE_SORT CELE_UPDOWN

Case ソート移動力
　Playsound Page.wav
　PageNum = 0
　CELE_SORT = 移動力
　Line 0 220 480 260 RGB(0, 0, 0) BF
　Font 20pt ゴシック Bold RGB(255, 255, 255)
　PaintString - - Now Loading…
　Font 10pt ゴシック Regular
　Refresh
　Call 出撃メンバーリスト作成 CELE_SORT CELE_UPDOWN

Case ソート加入順
　Playsound Page.wav
　PageNum = 0
　CELE_SORT = 加入
　Line 0 220 480 260 RGB(0, 0, 0) BF
　Font 20pt ゴシック Bold RGB(255, 255, 255)
　PaintString - - Now Loading…
　Font 10pt ゴシック Regular
　Refresh
　Call 出撃メンバーリスト作成 CELE_SORT CELE_UPDOWN

Case 終了
　Confirm この編成で出撃を終了しますか？
　If 選択 = 1 Then
　　Goto 出撃選択完了
　EndIf

Case Else
　If Left(選択,3) = "解除_" Then
　　Playsound Tub.wav
　　CELE_U_N = Right(選択,Len(選択) - 3)
　　ShowUnitStatus CELE_U_N
　　Set 新出撃リスト ""
　　For i = 1 To LLength(出撃リスト)
　　　If LIndex(出撃リスト,i) = CELE_U_N Then
　　　　Skip
　　　ElseIf LLength(新出撃リスト) = 0 Then
　　　　新出撃リスト = LIndex(出撃リスト,i)
　　　Else
　　　　新出撃リスト = (新出撃リスト & " " & LIndex(出撃リスト,i))
　　　EndIf
　　Next
　　出撃リスト = 新出撃リスト
　　UnSet 新出撃リスト

　Else
　　Playsound Type.wav
　　ShowUnitStatus 選択
　　If LLength(出撃リスト) = 0 Then
　　　出撃リスト = 選択
　　Else
　　　出撃リスト = (出撃リスト & " " & 選択)
　　EndIf
　EndIf
EndSw
Goto 出撃選択更新場面


出撃選択完了:
# 保存設定がオンの時、最終的な設定を変数として保存
If 出撃選択保存設定 = オン Then
　Set 出撃選択保存設定[内容] (CELE_SORT & " " & CELE_UPDOWN)
EndIf

ClearPicture
Refresh

# Cost_Organizeのやり方を参照
Set LAN_X[1] 0
Set LAN_Y[1] 0
Set LAN_X[2] -2
Set LAN_Y[2] 0
Set LAN_X[3] -1
Set LAN_Y[3] -1
Set LAN_X[4] -1
Set LAN_Y[4] 1
Set LAN_X[5] 0
Set LAN_Y[5] -2

Set LAN_X[6] 0
Set LAN_Y[6] 2
Set LAN_X[7] 1
Set LAN_Y[7] -1
Set LAN_X[8] 1
Set LAN_Y[8] 1
Set LAN_X[9] 2
Set LAN_Y[9] 0
Set LAN_X[10] -4
Set LAN_Y[10] 0
Set LAN_X[11] -3
Set LAN_Y[11] -1
Set LAN_X[12] -3
Set LAN_Y[12] 1
Set LAN_X[13] -2
Set LAN_Y[13] -2
Set LAN_X[14] -2
Set LAN_Y[14] 2
Set LAN_X[15] -1
Set LAN_Y[15] -3
Set LAN_X[16] -1
Set LAN_Y[16] 3
Set LAN_X[17] 0
Set LAN_Y[17] -4
Set LAN_X[18] 0
Set LAN_Y[18] 4
Set LAN_X[19] 1
Set LAN_Y[19] -3
Set LAN_X[20] 1
Set LAN_Y[20] 3

If Args(4) = スキップ Then
# オプションにスキップが設定されていたら配置しない。
Else
　For i = 1 To LLength(出撃リスト)
　　If Args(4) = "" Then
　　　Launch LIndex(出撃リスト,i) (Args(2) + LAN_X[i]) (Args(3) + LAN_Y[i])
　　Else
　　　Launch LIndex(出撃リスト,i) (Args(2) + LAN_X[i]) (Args(3) + LAN_Y[i]) Args(4)
　　EndIf
　Next
　UnSet 出撃リスト
EndIf

Font
UnSet CELE_SORT 
UnSet CELE_UPDOWN 
UnSet 味方リスト
UnSet LAN_X
UnSet LAN_Y
Return



出撃メンバーリスト作成:
# 選択可能な待機メンバーをリスト化

# リスト初期化
Set 味方リスト ""

# ■加入順、デフォルト
If Args(1) = 加入 Then
　ForEach 味方 待機
　　If LLength(味方リスト) = 0 Then
　　　味方リスト = 対象パイロット
　　ElseIf Args(2) = 降順 Then
　　　味方リスト = (対象パイロット & " " & 味方リスト)
　　Else
　　　味方リスト = (味方リスト & " " & 対象パイロット)
　　EndIf
　Next

# 以下は味方以外の陣営がリストに乗らないように判定。

# ■名称順。
ElseIf Args(1) = 名称 Then
　ForEach CELE_U_N In パイロット一覧(名称)
　　If (Party(CELE_U_N) = 味方) And _
	(Status(CELE_U_N) = 待機) And _
	(Pilot(UnitID(CELE_U_N),1) = CELE_U_N) Then
# サブパイロットもリストに載るのでメインパイロットのみを参照
　　Else
　　　Skip
　　EndIf
　　If LLength(ソートリスト) = 0 Then
　　　味方リスト = CELE_U_N
　　ElseIf Args(2) = 降順 Then
　　　味方リスト = (CELE_U_N & " " & 味方リスト)
　　Else
　　　味方リスト = (味方リスト & " " & CELE_U_N)
　　EndIf
　Next

# ■レベル順
ElseIf Args(1) = レベル Then
　ForEach CELE_U_N In パイロット一覧(レベル)
　　If (Party(CELE_U_N) = 味方) And _
	(Status(CELE_U_N) = 待機) And _
	(Pilot(UnitID(CELE_U_N),1) = CELE_U_N) Then
# サブパイロットもリストに載るのでメインパイロットのみを参照
　　Else
　　　Skip
　　EndIf
　　If LLength(味方リスト) = 0 Then
　　　味方リスト = CELE_U_N
　　ElseIf Args(2) = 降順 Then
　　　味方リスト = (CELE_U_N & " " & 味方リスト)
　　Else
　　　味方リスト = (味方リスト & " " & CELE_U_N)
　　EndIf
　Next

# ■ランク順
ElseIf Args(1) = ランク Then
　ForEach CELE_U_N In ユニット一覧(ランク)
　　If (Party(Pilot(CELE_U_N)) = 味方) And _
	(Status(Pilot(CELE_U_N)) = 待機) Then
　　Else
　　　Skip
　　EndIf
　　If LLength(ソートリスト) = 0 Then
　　　味方リスト = Pilot(CELE_U_N)
　　ElseIf Args(2) = 降順 Then
　　　味方リスト = (Pilot(CELE_U_N) & " " & 味方リスト)
　　Else
　　　味方リスト = (味方リスト & " " & Pilot(CELE_U_N))
　　EndIf
　Next

# ■ＨＰ順
ElseIf Args(1) = ＨＰ Then
　ForEach CELE_U_N In ユニット一覧(ＨＰ)
　　If (Party(Pilot(CELE_U_N)) = 味方) And _
	(Status(Pilot(CELE_U_N)) = 待機) Then
　　Else
　　　Skip
　　EndIf
　　If LLength(味方リスト) = 0 Then
　　　味方リスト = Pilot(CELE_U_N)
　　ElseIf Args(2) = 降順 Then
　　　味方リスト = (Pilot(CELE_U_N) & " " & 味方リスト)
　　Else
　　　味方リスト = (味方リスト & " " & Pilot(CELE_U_N))
　　EndIf
　Next

# ■移動力順
ElseIf Args(1) = 移動力 Then
　ForEach CELE_U_N In ユニット一覧(移動力)
　　If (Party(Pilot(CELE_U_N)) = 味方) And _
	(Status(Pilot(CELE_U_N)) = 待機) Then
　　Else
　　　Skip
　　EndIf
　　If LLength(味方リスト) = 0 Then
　　　味方リスト = Pilot(CELE_U_N)
　　ElseIf Args(2) = 降順 Then
　　　味方リスト = (Pilot(CELE_U_N) & " " & 味方リスト)
　　Else
　　　味方リスト = (味方リスト & " " & Pilot(CELE_U_N))
　　EndIf
　Next

EndIf
Return